compressedstack/CMakeLists.txt at master · 00ways/compressedstack · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
cmake_minimum_required(VERSION 3.16)


find_package(compressedarray)
project(compressedstack VERSION 1.0.0 LANGUAGES C)

set(CMAKE_C_STANDARD 17)
set(CMAKE_C_STANDARD_REQUIRED ON)
set(CMAKE_C_EXTENSIONS OFF)

add_library(compressedstack
    src/compressedstack.c
)
add_library(complib::Stack ALIAS compressedstack)

target_include_directories(compressedstack PUBLIC
    $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
    $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
)
if (compressedarray_FOUND)
    message(STATUS "Using installed compressedarray")
else()
    message(STATUS "Compilling compressedarray")
    add_subdirectory(deps/compressedarray)
endif()

target_link_libraries(compressedstack PRIVATE compressedarray)


include(GNUInstallDirs)
include(CMakePackageConfigHelpers)


configure_package_config_file(
  "cmake/compressedstackConfig.cmake.in"
  "compressedstackConfig.cmake"
  INSTALL_DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/compressedstack"
)

install(
    TARGETS compressedstack
    EXPORT compressedstackTargets
    ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)

install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/"
    DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
    FILES_MATCHING
        PATTERN "*.h"
)

install(EXPORT compressedstackTargets
    FILE compressedstackTargets.cmake
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/compressedstack
    NAMESPACE complib::
)

write_basic_package_version_file(
  "compressedstackConfigVersion.cmake"
  VERSION ${PROJECT_VERSION}
  COMPATIBILITY AnyNewerVersion
)


install(FILES
  "${CMAKE_CURRENT_BINARY_DIR}/compressedstackConfig.cmake"
  "${CMAKE_CURRENT_BINARY_DIR}/compressedstackConfigVersion.cmake"
  DESTINATION "${CMAKE_INSTALL_LIBDIR}/cmake/compressedstack"
)