Infinite/CMakeLists.txt at main · 014-code/Infinite · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
cmake_minimum_required(VERSION 3.25)
project(InfiniteEngine LANGUAGES CXX)

include(CTest)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

find_package(OpenGL REQUIRED)
find_package(glfw3 CONFIG REQUIRED)
find_package(GLEW REQUIRED)
find_package(glm CONFIG REQUIRED)
find_path(STB_IMAGE_INCLUDE_DIR NAMES stb/stb_image.h REQUIRED)
find_path(STB_TRUETYPE_INCLUDE_DIR NAMES stb/stb_truetype.h REQUIRED)
find_path(MINIAUDIO_INCLUDE_DIR NAMES miniaudio/miniaudio.h miniaudio.h REQUIRED)
find_library(MINIAUDIO_LIBRARY NAMES miniaudio REQUIRED)

set(ENGINE_SOURCES
    src/audio/AudioSystem.cpp
    src/audio/internal/AudioValidation.cpp
    src/audio/internal/AudioDeviceBackend.cpp
    src/audio/internal/AudioClipCache.cpp
    src/audio/internal/AudioMixerState.cpp
    src/audio/internal/AudioVoicePool.cpp
    src/audio/MusicPlayer.cpp
    src/audio/AudioEvent.cpp
    src/game/menu/MenuState.cpp
    src/game/menu/MenuStates.cpp
    src/particles/ParticleSystem.cpp
    src/save/SaveGame.cpp
    src/game/state/ApplicationStateStack.cpp
    src/physics/math/Aabb.cpp
    src/physics/math/Ray.cpp
    src/physics/math/Raycast.cpp
    src/physics/math/ClosestPoint.cpp
    src/physics/shapes/CollisionShape.cpp
    src/physics/world/ShapeCollision.cpp
    src/physics/world/PhysicsWorld.cpp
    src/physics/world/PhysicsQueries.cpp
    src/physics/world/PhysicsSolver.cpp
    src/physics/character/CharacterController.cpp
    src/graphics/shaders/SkinShaderSource.cpp
    src/graphics/lighting/DirectionalShadowSettings.cpp
    src/graphics/rendering/shadows/DirectionalShadowMap.cpp
    src/graphics/rendering/shadows/ShadowPassState.cpp
    src/animation/AnimationClip.cpp
    src/animation/AnimationSampler.cpp
    src/animation/AnimationPlayer.cpp
    src/animation/AnimationBlender.cpp
    src/animation/AnimationStateMachine.cpp
    src/animation/Skin.cpp
    src/assets/gltf/GltfSkinDecoder.cpp
    src/scene/SkinBinding.cpp
    src/assets/gltf/GltfAnimationDecoder.cpp
    src/graphics/materials/PbrParameters.cpp
    src/graphics/rendering/HdrPipeline.cpp
    src/resources/PbrResources.cpp
    src/resources/model/ModelTextureUploader.cpp
    src/assets/gltf/GltfPbrDecoder.cpp
    src/resources/PrimitiveResources.cpp
    src/scene/ScenePrimitives.cpp
    src/scene/serialization/PrimitiveSerialization.cpp
    src/scene/serialization/PendingSceneFile.cpp
    src/scene/serialization/SceneFileReader.cpp
    src/scene/serialization/SceneFileWriter.cpp
    src/scene/serialization/SceneBuilder.cpp
    src/graphics/geometry/primitives/PrimitiveMeshBuilder.cpp
    src/assets/GltfLoader.cpp
    src/assets/gltf/GltfFileReader.cpp
    src/assets/gltf/GltfMaterialDecoder.cpp
    src/assets/gltf/GltfMeshDecoder.cpp
    src/assets/gltf/GltfNodeDecoder.cpp
    src/assets/gltf/GltfValidator.cpp
    src/assets/MaterialLoader.cpp
    src/assets/MeshLoader.cpp
    src/core/Application.cpp
    src/core/ApplicationLoop.cpp
    src/core/FrameTiming.cpp
    src/core/FramePerformance.cpp
    src/core/Log.cpp
    src/core/Time.cpp
    src/core/ResourcePath.cpp
    src/input/Input.cpp
    src/input/InputState.cpp
    src/input/ActionMap.cpp
    src/math/Transform.cpp
    src/ui/UiElement.cpp
    src/ui/UiButton.cpp
    src/ui/UiCanvas.cpp
    src/ui/font/Utf8.cpp
    src/ui/font/FontFile.cpp
    src/ui/font/FontCollection.cpp
    src/ui/font/BuiltinFont.cpp
    src/ui/font/FontAtlas.cpp
    src/ui/text/TextLayout.cpp
    src/ui/UiRenderer.cpp
    src/scene/GameObject.cpp
    src/scene/components/Component.cpp
    src/scene/components/AreaComponent.cpp
    src/scene/components/CharacterBodyComponent.cpp
    src/scene/components/AudioSourceComponent.cpp
    src/scene/components/PhysicsTransformRules.cpp
    src/scene/components/ScriptComponent.cpp
    src/scene/Scene.cpp
    src/scene/systems/SceneAudioSync.cpp
    src/scene/systems/ScenePhysicsSync.cpp
    src/scene/systems/SceneRenderCollector.cpp
    src/scene/SceneManager.cpp
    src/scene/SceneSerializer.cpp
    src/scene/ModelInstantiator.cpp
    src/scene/components/Renderable.cpp
    src/scene/components/PhysicsBodyComponent.cpp
    src/platform/Window.cpp
    src/resources/ResourceManager.cpp
    src/resources/Model.cpp
    src/graphics/camera/Camera.cpp
    src/graphics/lighting/Lighting.cpp
    src/graphics/lighting/SceneLighting.cpp
    src/graphics/lighting/LightingUniforms.cpp
    src/graphics/geometry/Mesh.cpp
    src/graphics/resources/Material.cpp
    src/graphics/rendering/OpenGLDebug.cpp
    src/graphics/resources/ImageLoader.cpp
    src/graphics/rendering/Renderer.cpp
    src/graphics/rendering/RenderItem.cpp
    src/graphics/resources/Shader.cpp
    src/graphics/resources/Texture.cpp
)

# 框架层只编译可复用的引擎模块，不包含任何具体示例的主程序和资源。
add_library(infinite_engine STATIC ${ENGINE_SOURCES})
target_include_directories(infinite_engine PUBLIC src)

# GLSL保留为可独立阅读的源文件，构建时嵌入引擎，运行时无需复制或查找默认Shader。
set(PRIMITIVE_SHADER_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/src/graphics/shaders")
set_property(DIRECTORY APPEND PROPERTY CMAKE_CONFIGURE_DEPENDS
    "${PRIMITIVE_SHADER_DIRECTORY}/primitive.vert" "${PRIMITIVE_SHADER_DIRECTORY}/primitive.frag"
    "${PRIMITIVE_SHADER_DIRECTORY}/scene_lighting.glsl")
file(READ "${PRIMITIVE_SHADER_DIRECTORY}/primitive.vert" PRIMITIVE_VERTEX_SOURCE)
file(READ "${PRIMITIVE_SHADER_DIRECTORY}/primitive.frag" PRIMITIVE_FRAGMENT_SOURCE)
file(READ "${PRIMITIVE_SHADER_DIRECTORY}/scene_lighting.glsl" SCENE_LIGHTING_SOURCE)
string(REPLACE "// @scene_lighting@" "${SCENE_LIGHTING_SOURCE}"
    PRIMITIVE_FRAGMENT_SOURCE "${PRIMITIVE_FRAGMENT_SOURCE}")
configure_file("${PRIMITIVE_SHADER_DIRECTORY}/PrimitiveShaderSources.h.in"
    "${CMAKE_CURRENT_BINARY_DIR}/generated/PrimitiveShaderSources.h" @ONLY)
target_include_directories(infinite_engine PRIVATE "${CMAKE_CURRENT_BINARY_DIR}/generated")
include(cmake/PbrShaders.cmake)

# stb只在实现文件中使用，不成为引擎公开头文件的依赖。
target_include_directories(infinite_engine SYSTEM PRIVATE ${STB_IMAGE_INCLUDE_DIR})
target_include_directories(infinite_engine SYSTEM PRIVATE ${STB_TRUETYPE_INCLUDE_DIR})
target_include_directories(infinite_engine SYSTEM PRIVATE ${MINIAUDIO_INCLUDE_DIR})
target_include_directories(infinite_engine SYSTEM PRIVATE third_party/cgltf)
install(FILES third_party/cgltf/cgltf.h third_party/cgltf/README.md DESTINATION third-party-licenses/cgltf)
target_compile_options(infinite_engine PRIVATE -Wall -Wextra)
target_link_libraries(infinite_engine PUBLIC
    glfw
    GLEW::GLEW
    glm::glm
    OpenGL::GL
    ${MINIAUDIO_LIBRARY}
)

set(RUNTIME_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/runtime" CACHE PATH "Example runtime output root")
get_filename_component(MINGW_BIN_DIRECTORY "${CMAKE_CXX_COMPILER}" DIRECTORY)
install(FILES "${CMAKE_CURRENT_SOURCE_DIR}/docs/交付运行说明.md" DESTINATION ".")
# 附带本机MSYS2提供的第三方许可文件；这并不替代项目自身的发布授权检查。
if(MINGW)
    foreach(DEPENDENCY IN ITEMS gcc libgcc libstdc++ libwinpthread glfw glew glm stb miniaudio)
        set(LICENSE_DIRECTORY "${MINGW_BIN_DIRECTORY}/../share/licenses/${DEPENDENCY}")
        if(EXISTS "${LICENSE_DIRECTORY}")
            install(DIRECTORY "${LICENSE_DIRECTORY}" DESTINATION "third-party-licenses")
        else()
            message(WARNING "Missing distribution license directory: ${DEPENDENCY}")
        endif()
    endforeach()
endif()

# 示例目标、资源同步和安装规则集中在独立文件，新增示例时只需维护该模块。
include(cmake/EngineExamples.cmake)

if(BUILD_TESTING)
    include(cmake/EngineTests.cmake)
endif()