mkdev/flake.nix at main · 4jamesccraven/mkdev · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
{
  description = "Save your boilerplate instead of writing it.";

  inputs.nixpkgs.url = "https://channels.nixos.org/nixos-25.11/nixexprs.tar.xz";

  outputs =
    {
      self,
      nixpkgs,
      ...
    }:
    let
      inherit (nixpkgs) lib;

      eachDefaultSystem =
        func: lib.genAttrs lib.systems.flakeExposed (system: func nixpkgs.legacyPackages.${system});
    in
    {

      packages = eachDefaultSystem (
        pkgs:
        let
          inherit (pkgs.stdenv.hostPlatform) system;
        in
        {
          default = self.packages.${system}.mkdev;
          mkdev = pkgs.callPackage ./nix/mkdev.nix { };
          mkf = pkgs.callPackage ./nix/mkf.nix { };
        }
      );

      overlays.default = prev: final: {
          mkdev = prev.callPackage ./nix/mkdev.nix { };
          mkf = prev.callPackage ./nix/mkf.nix { };
        };

      homeManagerModules.default = import ./nix/home-manager.nix;
      homeManagerModule = # .
        lib.warn # .
          "mkdev: The option `homeManagerModule' has been renamed to `homeManagerModules.default'." # .
          self.homeManagerModules.default;

      devShells = eachDefaultSystem (pkgs: {
        default = pkgs.mkShell {
          buildInputs = with pkgs; [
            # Rust
            cargo
            clippy
            libgcc
            rustc

            # Nix
            statix

            # Bash
            argbash

            # Misc.
            gh
          ];

          RUST_SRC_PATH = "${pkgs.rustPlatform.rustLibSrc}";
        };
      });

    };
}