stackandconquer/stackandconquer.pro at main · ElTh0r0/stackandconquer · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
# SPDX-FileCopyrightText: 2015-2025 Thorsten Roth
# SPDX-License-Identifier: GPL-3.0-or-later

equals(QT_MAJOR_VERSION, 5):lessThan(QT_MINOR_VERSION, 12) {
  error("StackAndConquer requires Qt 5.12 or greater")
}

TEMPLATE      = app

unix: !macx {
       TARGET = stackandconquer
} else {
       TARGET = StackAndConquer
}

win32:VERSION  = 0.12.0.0
else:VERSION   = 0.12.0

QMAKE_TARGET_PRODUCT     = "StackAndConquer"
QMAKE_TARGET_DESCRIPTION = "Challenging tower conquest board game"
QMAKE_TARGET_COPYRIGHT   = "(C) 2015-present Thorsten Roth"

DEFINES      += APP_NAME=\"\\\"$$QMAKE_TARGET_PRODUCT\\\"\" \
                APP_VERSION=\"\\\"$$VERSION\\\"\" \
                APP_DESC=\"\\\"$$QMAKE_TARGET_DESCRIPTION\\\"\" \
                APP_COPY=\"\\\"$$QMAKE_TARGET_COPYRIGHT\\\"\"

MOC_DIR       = ./.moc
OBJECTS_DIR   = ./.objs
UI_DIR        = ./.ui
RCC_DIR       = ./.rcc

QT           += core gui qml widgets
lessThan(QT_MAJOR_VERSION, 6) {
  QT         += svg
} else {
  QT         += svgwidgets
}
CONFIG       += c++11
DEFINES      += QT_NO_FOREACH

CONFIG(debug, debug|release) {
  CONFIG     += warn_on
  QMAKE_CXXFLAGS += -Wall -Wextra -pedantic
  DEFINES    += QT_DISABLE_DEPRECATED_BEFORE=0x061000
}

SOURCES      += main.cpp\
                stackandconquer.cpp \
                game.cpp \
                board.cpp \
                player.cpp \
                settings.cpp \
                settingsdialog.cpp \
                opponentjs.cpp \
                generateboard.cpp

HEADERS      += stackandconquer.h \
                game.h \
                board.h \
                player.h \
                settings.h \
                settingsdialog.h \
                opponentjs.h \
                generateboard.h

FORMS        += stackandconquer.ui \
                settingsdialog.ui

RESOURCES    += data/data.qrc \
                lang/translations.qrc

TRANSLATIONS += lang/stackandconquer_de.ts \
                lang/stackandconquer_en.ts \
                lang/stackandconquer_it.ts \
                lang/stackandconquer_ja_JP.ts \
                lang/stackandconquer_nl.ts \
                lang/stackandconquer_pl.ts \
                lang/stackandconquer_ru.ts

win32:RC_FILE = data/win.rc

macx {
  ICON               = icons/icon.icns
  QMAKE_INFO_PLIST   = data/mac/Info.plist

  CPU_DATA.path      = Contents/Resources
  CPU_DATA.files    += data/cpu
  CPU_DATA.files    += data/boards
  QMAKE_BUNDLE_DATA += CPU_DATA
}

unix: !macx {
  isEmpty(PREFIX) {
    PREFIX = /usr/local
  }
  isEmpty(BINDIR) {
    BINDIR = bin
  }

  target.path    = $$PREFIX/$$BINDIR/

  data.path      = $$PREFIX/share/stackandconquer
  data.files    += data/cpu
  data.files    += data/boards

  desktop.path   = $$PREFIX/share/applications
  desktop.files += data/unix/com.github.elth0r0.stackandconquer.desktop

  icons.path     = $$PREFIX/share/icons
  icons.files   += icons/hicolor

  man.path       = $$PREFIX/share/man
  # Specify each subfolder - otherwise CMakeLists.txt will be installed
  man.files     += man/man6
  man.files     += man/de
  man.files     += man/it
  man.files     += man/ru

  meta.path      = $$PREFIX/share/metainfo
  meta.files    += data/unix/com.github.elth0r0.stackandconquer.metainfo.xml

  INSTALLS      += target \
                   data \
                   desktop \
                   icons \
                   man \
                   meta
}