build.gradle

plugins {
	id 'java-library'
	id 'maven-publish'
	id 'io.spring.dependency-management' version '1.1.7'
}

group = 'com.fhsh.daitda'
version = '0.1.3-SNAPSHOT'

java {
	toolchain {
		languageVersion = JavaLanguageVersion.of(17)
	}
}

configurations {
	compileOnly {
		extendsFrom annotationProcessor
	}
}

repositories {
	mavenCentral()
}

dependencyManagement {
	imports {
		mavenBom "org.springframework.boot:spring-boot-dependencies:3.5.13"
	}
}

dependencies {
	api 'org.springframework.boot:spring-boot-starter-data-jpa'
	api 'com.querydsl:querydsl-jpa:5.0.0:jakarta'

	implementation 'org.springframework.boot:spring-boot-starter-web'
	compileOnly 'org.projectlombok:lombok'
	annotationProcessor 'org.projectlombok:lombok'

	// querydsl
	annotationProcessor 'com.querydsl:querydsl-apt:5.0.0:jakarta'
	annotationProcessor 'jakarta.annotation:jakarta.annotation-api'
	annotationProcessor 'jakarta.persistence:jakarta.persistence-api'

	testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

def env = [:]
def envFile = rootProject.file(".env")

if (envFile.exists()) {
	envFile.eachLine { line ->
		if (line && !line.startsWith("#") && line.contains("=")) {
			def (key, value) = line.split("=", 2)
			env[key.trim()] = value.trim()
		}
	}
}

publishing {
	publications {
		gpr(MavenPublication) {
			from components.java
			artifactId = 'common'
		}
	}
	repositories {
		maven {
			name = "GitHubPackages"
			url = uri("https://maven.pkg.github.com/FiveHandSixHand/common-service")
			credentials {
				username = System.getenv("GITHUB_USERNAME")
				password = System.getenv("GITHUB_TOKEN")
			}
		}
	}
}

tasks.named('test') {
	useJUnitPlatform()
}

tasks.withType(GenerateModuleMetadata).configureEach {
	suppressedValidationErrors.add('dependencies-without-versions')
}

tasks.withType(JavaCompile).configureEach {
	options.encoding = 'UTF-8'
}