dotfiles/flake.nix at wrapped · RaySlash/dotfiles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
{
  description = "Dotfiles (rayslash)";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    nixpkgs-stable.url = "github:nixos/nixpkgs?ref=nixos-25.11";
    flake-parts.url = "github:hercules-ci/flake-parts";

    wrappers = {
      url = "github:BirdeeHub/nix-wrapper-modules";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nurpkgs = {
      url = "github:nix-community/NUR";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nix-index-database = {
      url = "github:Mic92/nix-index-database";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    zen-browser = {
      url = "github:0xc000022070/zen-browser-flake";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{ flake-parts, ... }:
    let
      lib = inputs.nixpkgs.lib;
    in
    flake-parts.lib.mkFlake { inherit inputs; } {
      imports = [
        inputs.flake-parts.flakeModules.flakeModules
        inputs.wrappers.flakeModules.wrappers
      ];
      systems = inputs.nixpkgs.lib.platforms.all;
      perSystem =
        {
          config,
          self',
          inputs',
          pkgs,
          system,
          ...
        }:
        {
          packages = import ./packages { inherit pkgs inputs; };
          # wrappers = import ./wrappers.nix { inherit pkgs inputs; };
          formatter = inputs'.nixpkgs.legacyPackages.alejandra;

          _module.args.pkgs = import inputs.nixpkgs {
            inherit system;
            config.allowUnfree = true;
            overlays = builtins.attrValues inputs.self.overlays;
          };
        };
      flake = {
        overlays = import ./overlays.nix { inherit inputs; };
        wrappers = import ./wrappers.nix { inherit inputs; };
        flakeModules.default = import ./flake-module.nix { inherit inputs lib; };
        nixosConfigurations = import ./systems { inherit inputs lib; };
        nixosModules = import ./systems/modules { inherit inputs lib; };
      };
    };
}