controller/build.gradle at main · Realm-MC/controller · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
plugins {
    id 'java'
    id 'com.github.johnrengelman.shadow' version '7.1.0'
    id 'maven-publish'
}

group = 'com.realmmc.controller'
version = '1.0'

repositories {
    mavenCentral()
    mavenLocal()
    maven {
        name = 'papermc'
        url = 'https://repo.papermc.io/repository/maven-public/'
    }
    maven { url = uri("https://repo.codemc.io/repository/maven-releases/") }
    maven {
        url = uri("https://repo.opencollab.dev/main/")
    }
    maven { url = uri("https://repo.codemc.io/repository/maven-snapshots/") }
    maven { url = uri("https://repo.viaversion.com") }
}

dependencies {
    implementation("com.velocitypowered:velocity-api:3.4.0-SNAPSHOT")
    annotationProcessor("com.velocitypowered:velocity-api:3.4.0-SNAPSHOT")
    implementation("com.fasterxml.jackson.core:jackson-databind:2.20.0")
    compileOnly("org.projectlombok:lombok:1.18.40")
    annotationProcessor("org.projectlombok:lombok:1.18.40")
    implementation("redis.clients:jedis:6.1.0")
    implementation("net.kyori:adventure-text-minimessage:4.24.0")
    implementation("net.kyori:adventure-text-serializer-legacy:4.14.0")
    implementation("org.mongodb:mongodb-driver-sync:4.11.1")
    compileOnly("io.papermc.paper:paper-api:1.21.4-R0.1-SNAPSHOT")
    compileOnly("com.github.retrooper:packetevents-spigot:2.9.5")
    compileOnly('org.geysermc.geyser:api:2.8.3-SNAPSHOT')
    implementation("com.maxmind.geoip2:geoip2:4.0.1")
    compileOnly("com.viaversion:viaversion-api:5.5.1")
    implementation("org.apache.logging.log4j:log4j-core:2.25.2")
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
    sourceCompatibility = JavaVersion.VERSION_21
    targetCompatibility = JavaVersion.VERSION_21
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
}

tasks.shadowJar {
    archiveBaseName.set('controller')
    archiveClassifier.set('')
    archiveVersion.set(project.version.toString())
    mergeServiceFiles()
    exclude('META-INF/*.RSA', 'META-INF/*.SF', 'META-INF/*.DSA')
}

tasks.build {
    dependsOn tasks.shadowJar
}

tasks.withType(PublishToMavenRepository).configureEach {
    dependsOn tasks.shadowJar
}

publishing {
    publications {
        maven(MavenPublication) {
            groupId = project.group.toString()
            artifactId = 'controller'
            version = project.version.toString()
            artifact(tasks.shadowJar)
        }
    }

    repositories {
        maven {
            name = "GitHubPackages"
            def repo = System.getenv("GITHUB_REPOSITORY") ?: "Realm-MC/controller"
            url = uri("https://maven.pkg.github.com/${repo}")

            credentials {
                username = findProperty("gpr.user")?.toString() ?: System.getenv("GITHUB_ACTOR")
                password = findProperty("gpr.token")?.toString() ?: System.getenv("GITHUB_TOKEN")
            }
        }
    }
}