csharp-language-server/flake.nix at main · SofusA/csharp-language-server · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
{
  description = "A flake for csharp-language-server";

  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    naersk.url = "github:nix-community/naersk";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    rust-overlay.url = "github:oxalica/rust-overlay";
  };

  outputs = {
    flake-utils,
    naersk,
    nixpkgs,
    rust-overlay,
    ...
  }:
    let
      overlays = {
        default = final: prev: {
          csharp-language-server = (final.callPackage naersk { }).buildPackage {
            pname = "csharp-language-server";
            src = ./.;

            nativeBuildInputs = [ final.dotnetCorePackages.dotnet_8.sdk ];

            cargoTestOptions = x: x ++ [
              "--" "--skip=first_line_is_jsonrpc"
            ];
          };
        };
      };
    in
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ (import rust-overlay) overlays.default ];
        };
      in
      {
        devShells.default = pkgs.mkShell {
          buildInputs = [ pkgs.csharp-language-server ];
        };

        packages = {
          default = pkgs.csharp-language-server;

          csharp-language-server = throw ''
            packages.csharp-language-server has been renamed to packages.default.
          '';
        };
      }
    ) // {
      inherit overlays;
    };
}