build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.5.6'
    id 'io.spring.dependency-management' version '1.1.7'
    id 'org.asciidoctor.jvm.convert' version '4.0.5'
    id "io.sentry.jvm.gradle" version "6.0.0"
}

group = 'com.todaysound'
version = '0.0.1-SNAPSHOT'
description = 'Demo project for Spring Boot'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
    asciidoctorExt
}

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-aop'
    implementation 'org.springframework.boot:spring-boot-starter-actuator'


    // 1. Sentry
    implementation platform('io.sentry:sentry-bom:8.31.0')
    implementation 'io.sentry:sentry-spring-boot-starter-jakarta'
    implementation 'io.sentry:sentry-logback'

    // P6Spy Spring Boot Starter
    implementation 'com.github.gavlyukovskiy:p6spy-spring-boot-starter:1.9.1'

    // Micrometer Metrics
    implementation 'io.micrometer:micrometer-registry-prometheus' // Prometheus

    // Micrometer Tracing - traceId/spanId 자동 생성
    implementation 'io.micrometer:micrometer-tracing-bridge-brave'
    // Tempo로 trace export (Zipkin wire format).
    // Spring Boot 3.5 BOM이 io.zipkin.reporter2 그룹을 3.5.x 버전으로 관리.
    // ("reporter3" 그룹은 존재하지 않음 — 그룹명은 reporter2 유지하고 내부 버전만 v3로 올라옴.)
    // - reporter-brave: Brave Span → Zipkin V2 모델 변환
    // - sender-urlconnection: 실제 HTTP POST. Sender 없으면 ZipkinSpanHandler 빈 생성 안 됨
    implementation 'io.zipkin.reporter2:zipkin-reporter-brave'
    implementation 'io.zipkin.reporter2:zipkin-sender-urlconnection'

    // 구조화된 JSON 로깅
    implementation 'net.logstash.logback:logstash-logback-encoder:8.0'

    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.mysql:mysql-connector-j'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.7.0'


    // RestDocs
    asciidoctorExt 'org.springframework.restdocs:spring-restdocs-asciidoctor'
    testImplementation 'org.springframework.restdocs:spring-restdocs-mockmvc'

    // QueryDsl
    implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
    annotationProcessor "com.querydsl:querydsl-apt:5.0.0:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    // Firebase Admin SDK
    implementation 'com.google.firebase:firebase-admin:9.2.0'

    // test containers
    testImplementation "org.testcontainers:testcontainers"
    testImplementation 'org.testcontainers:mysql'
    testImplementation 'org.testcontainers:jdbc'
    testImplementation 'org.testcontainers:junit-jupiter'

    // flyway
    implementation 'org.flywaydb:flyway-core:11.20.1'
    implementation 'org.flywaydb:flyway-mysql'

}

tasks.named('test') {
    useJUnitPlatform()
}

ext { // 전역 변수
    snippetsDir = file("build/generated-snippets")
}

test { // test 실행 후 결과를 snippetsDir에 저장
    outputs.dir snippetsDir

    afterTest { desc, result ->
        if (result.resultType == TestResult.ResultType.FAILURE) { // 테스트가 실패했다면?
            println("🔴 FAILED TEST: " + desc.getDisplayName())  // 실패한 테스트 이름 출력
            println("======================================")
            result.exception?.printStackTrace()                  // 상세 에러 내용 출력
            println("======================================")
        }
    }
}

asciidoctor { // adoc 문서 파일을 읽어서 HTML로 변환
    inputs.dir snippetsDir
    configurations 'asciidoctorExt'

    sources { // 특정 파일만 html로 만들
        include('**/index.adoc')
    }
    baseDirFollowsSourceDir()
    dependsOn test
}

tasks.register('copyDocument', Copy) { // 8
    dependsOn asciidoctor

    from file("build/docs/asciidoc")
    into file("docs")
}

asciidoctor.doFirst {
    delete file('docs')
}


bootJar { // 생성된 HTML 파일을 static/docs 폴더에 복사
    dependsOn asciidoctor
    from("${asciidoctor.outputDir}") {
        into 'static/docs'
    }
}

sentry {
    // 소스 코드를 센트리에 업로드하여 에러 발생 시 코드 문맥을 보여줍니다.
    includeSourceContext = true

    org = "todaysound"
    projectName = "java-spring-boot"

    authToken = System.getenv("SENTRY_AUTH_TOKEN")
}