ADMeshGUI/ADMeshGUI.pro at master · admesh/ADMeshGUI · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
#-------------------------------------------------
#
# Project created by QtCreator 2014-10-31T11:28:53
#
# [Information about Qt + OpenGL classes (e.g. how to use the API) obtained from Qt Reference Pages
# http://doc.qt.io/qt-5/reference-overview.html 9. 5. 2015]
#
#-------------------------------------------------

QT       += core gui opengl widgets svg

lessThan(QT_MAJOR_VERSION, 5) {
   error(ADMeshGUI requires Qt 5.4 to run. Older version detected.)
}

equals(QT_MAJOR_VERSION, 5):lessThan(QT_MINOR_VERSION, 4) {
   error(ADMeshGUI requires Qt 5.4 to run. Older version detected.)
}

TARGET = admeshgui
TEMPLATE = app

load(uic)
uic.commands += -tr _

SOURCES += main.cpp\
        window.cpp \
    renderingwidget.cpp \
    admeshcontroller.cpp \
    meshobject.cpp \
    historylist.cpp \
    propertiesdialog.cpp

HEADERS  += window.h \
    data.h \
    renderingwidget.h \
    admeshcontroller.h \
    meshobject.h \
    historylist.h \
    propertiesdialog.h \
    admeshEventFilter.h

FORMS    += window.ui \
    propertiesdialog.ui

LIBS += -ladmesh -lstlsplit
macx {
    LIBS += -lintl
    TARGET = ADMeshGUI
    ICON = Resources/admeshgui.icns
    QMAKE_INFO_PLIST = Distribution/Info.plist
    include(homebrew.pri)
    app.files += ADMesGUI.app
    app.path = /Applications
    INSTALLS += app
}

win32 {
    LIBS += -lintl -liconv
    RC_FILE = admeshgui.rc
}

unix {
    isEmpty(PREFIX):PREFIX = /usr
    bin.files += admeshgui
    bin.path = $$PREFIX/bin
    mainico.files += Resources/admeshgui.svg
    mainico.path = $$PREFIX/share/icons/hicolor/scalable/apps
    16ico.files += Distribution/16x16/admeshgui.png
    16ico.path = $$PREFIX/share/icons/hicolor/16x16/apps
    32ico.files += Distribution/32x32/admeshgui.png
    32ico.path = $$PREFIX/share/icons/hicolor/32x32/apps
    48ico.files += Distribution/48x48/admeshgui.png
    48ico.path = $$PREFIX/share/icons/hicolor/48x48/apps
    symbico.files += Distribution/symbolic/admeshgui-symbolic.svg
    symbico.path = $$PREFIX/share/icons/hicolor/symbolic/apps
    desktop.files += Distribution/admeshgui.desktop
    desktop.path = $$PREFIX/share/applications
    appdata.files += Distribution/admeshgui.appdata.xml
    appdata.path = $$PREFIX/share/appdata
    INSTALLS += bin desktop mainico 16ico 32ico 48ico symbico appdata
}

DISTFILES += \
    fshader.glsl \
    vshader.glsl

RESOURCES += \
    shaders.qrc \
    Resources.qrc

OTHER_FILES += \
    picking_vshader.glsl \
    picking_fshader.glsl \
    Info.plist \
    homebrew.pri \
    Distribution/admeshgui.ico \
    admeshgui.rc