cpp-lox/meson.build at master · ananthvk/cpp-lox · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
project(
    'cpplox',
    'cpp',
    version: '1.0.8',
    default_options: [
        'warning_level=3',
        'cpp_std=c++20',
    ],
)

# Make the executable static so that dll/so version mismatch can be avoided
system = host_machine.system()
if system == 'windows'
    add_project_arguments(['-static-libstdc++', '-static-libgcc'], language: 'cpp')
elif system == 'linux'
    add_project_arguments(['-static-libstdc++', '-static-libgcc'], language: 'cpp')
elif system == 'darwin'
    add_project_arguments(['-stdlib=libc++'], language: 'cpp')
endif

include_dirs = include_directories(['include', 'thirdparty'])
project_deps = [dependency('fmt', static: true)]

# Sources used by all binaries
common_sources = files(
    'src/common/allocator.cpp',
    'src/common/chunk.cpp',
    'src/common/debug_vm.cpp',
    'src/common/gc.cpp',
    'src/common/value.cpp',
)

# Sources used only by the compiler
compiler_sources = files(
    'src/compiler/compiler.cpp',
    'src/compiler/debug_compiler.cpp',
    'src/compiler/lexer.cpp',
    'src/compiler/parser.cpp',
)

# Sources used only by the VM
vm_sources = files(
    'src/native/classes.cpp',
    'src/native/list.cpp',
    'src/native/map.cpp',
    'src/native/math.cpp',
    'src/native/memory.cpp',
    'src/native/stdio.cpp',
    'src/native/stdlib.cpp',
    'src/native/string.cpp',
    'src/native/test.cpp',
    'src/native/time.cpp',
    'src/vm/register_native_functions.cpp',
    'src/vm/vm.cpp',
)

# Sources used by serialization
serialization_sources = files(
    'src/serialization/deserializer.cpp',
    'src/serialization/serializer.cpp',
)

# Sources used by the lox library
lox_sources = files('src/lox/lox.cpp')

# Stubs
compiler_stub = files('src/stubs/compiler_stub.cpp')

subdir('flags')
subdir('src')

if get_option('enable-tests')
    subdir('tests')
endif

if get_option('enable-benchmarks')
    subdir('benchmarks')
endif