TestDataTable/TestTools/RobotFramework/TDTClient.robot at master · damies13/TestDataTable · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
*** Settings ***
Library    TDT.py
# Library    TDT.py     http://localhost
# Library    TDT.py     http://DavesMBPSG

Suite Setup		TDT Client Init
Suite Teardown	TDT Client End


*** Variables ***
${table}=	TDTClientTest
${column}=	Column A
${tstval}=	test value

*** Test Cases ***

Send Value
	${resp}=	TDT Send Value		${table}	${column}		${tstval}
	Should Be Equal As Strings  	201 	${resp}

Get Value
	${value1}=	TDT Get Value		${table}	${column}
	Should Be Equal 	${tstval}	${value1}
	${value2}=	TDT Get Value		${table}	${column}
	Should Not Be Equal 	${tstval}	${value2}
	Should Be Empty    ${value2}
	# return value
	TDT Send Value		${table}	${column}		${value1}

Send Value Unique
	${resp}=	TDT Send Value Unique		${table}	${column}		${tstval}_zzz
	Should Be Equal As Strings  	201 	${resp}
	${resp}=	TDT Send Value Unique		${table}	${column}		${tstval}_zzz
	Should Be Equal As Strings  	200 	${resp}

Send Row
	&{dict} =	Create Dictionary	c1=xyz	c2=abc	c3=123
	${resp}=	TDT Send Row		${table}	${dict}
	Should Be Equal As Strings  	201 	${resp}

Get Row
	TDT Send Value		${table}	Column B	Another value
	TDT Send Value		${table}	Column C	Column C value
	TDT Send Value		${table}	Column D	Column D value
	${values}=	TDT Get Row		${table}
	Should Be Equal 	${values['Column D']} 	Column D value
	TDT Send Row		${table}	${values}

Delete Column
	TDT Send Value		${table}	Column Del	Another value
	TDT Send Value		${table}	Column Del	Another value 2
	${value1}=	TDT Get Value		${table}	Column Del
	Should Be Equal 	Another value	${value1}
	${resp}=	TDT Delete Column	${table}	Column Del
	Should Be Equal As Strings  	200 	${resp}
	${ret}= 	Run Keyword And Return Status	TDT Get Value		${table}	Column Del
	Should Be Equal As Strings		${ret}		False

Delete Table
	${resp}=	TDT Delete Table	${table}
	Should Be Equal As Strings  	200 	${resp}
	${ret}= 	Run Keyword And Return Status	TDT Get Row		${table}
	Should Be Equal As Strings		${ret}		False

*** Keywords ***
TDT Client Init
	${secs} =	Get Time	epoch
	Set Suite Variable	${table}	TDTTest_${secs}

TDT Client End
	TDT Delete Table	${table}


#