TaskManager/build.gradle at main · deanxbox/TaskManager · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
plugins {
    id 'net.fabricmc.fabric-loom' version "${loom_version}"
    id 'maven-publish'
}

version = project.mod_version
group = project.maven_group

base {
    archivesName = project.archives_base_name
}

loom {
    splitEnvironmentSourceSets()

    mods {
        "taskmanager" {
            sourceSet sourceSets.main
            sourceSet sourceSets.client
        }
    }
}

repositories {
    maven { url = 'https://maven.terraformersmc.com/releases/' }
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    implementation "net.fabricmc:fabric-loader:${project.loader_version}"
    implementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"
    compileOnly "com.terraformersmc:modmenu:${project.modmenu_version}"
}

processResources {
    inputs.property "version", project.version
    inputs.property "minecraft_version", project.minecraft_version
    inputs.property "loader_version", project.loader_version
    filteringCharset "UTF-8"

    filesMatching("fabric.mod.json") {
        expand "version": project.version,
                "minecraft_version": project.minecraft_version,
                "loader_version": project.loader_version
    }
}

def targetJavaVersion = 25
tasks.withType(JavaCompile).configureEach {
    it.options.encoding = "UTF-8"
    if (targetJavaVersion >= 10 || JavaVersion.current().isJava10Compatible()) {
        it.options.release.set(targetJavaVersion)
    }
}

java {
    def javaVersion = JavaVersion.toVersion(targetJavaVersion)
    if (JavaVersion.current() < javaVersion) {
        toolchain.languageVersion = JavaLanguageVersion.of(targetJavaVersion)
    }
    withSourcesJar()
    sourceCompatibility = JavaVersion.toVersion(targetJavaVersion)
    targetCompatibility = JavaVersion.toVersion(targetJavaVersion)
}

sourceSets {
    test {
        java.srcDirs = ['src/test/java']
        compileClasspath += sourceSets.main.output + sourceSets.client.output + configurations.compileClasspath + configurations.clientCompileClasspath
        runtimeClasspath += output + compileClasspath + sourceSets.main.output + sourceSets.client.output + configurations.runtimeClasspath + configurations.clientRuntimeClasspath
    }
}

tasks.register('runTaskManagerTests', JavaExec) {
    group = 'verification'
    description = 'Runs TaskManager deterministic unit checks.'
    classpath = sourceSets.test.runtimeClasspath
    mainClass = 'wueffi.taskmanager.client.TaskManagerTestRunner'
    dependsOn tasks.named('testClasses')
}

tasks.named('test') {
    failOnNoDiscoveredTests = false
}

tasks.named('check') {
    dependsOn tasks.named('runTaskManagerTests')
}

jar {
    from("LICENSE") {
        rename { "${it}_${project.archives_base_name}" }
    }
    manifest {
        attributes(
                "Premain-Class": "wueffi.taskmanager.MemoryAgent"
        )
    }
}

publishing {
    publications {
        create("mavenJava", MavenPublication) {
            artifactId = project.archives_base_name
            from components.java
        }
    }

    repositories {
    }
}