Common.ArrayUtils.pas

unit Common.ArrayUtils;

interface

uses
  System.Generics.Defaults;

type
  TArrayUtils = record
    class function IndexOf<T>( const A: TArray<T>; const Value: T ): Integer; static;
    class function Remove<T>( var A: TArray<T>; const Value: T ): Boolean; static;
    class function RemoveAll<T>( var A: TArray<T>; const Value: T ): Integer; static;
  end;

implementation

class function TArrayUtils.IndexOf<T>( const A: TArray<T>; const Value: T ): Integer;
var
  Cmp: IEqualityComparer<T>;
  I: Integer;
begin
  Cmp := TEqualityComparer<T>.Default;
  for I := 0 to High( A ) do
    if Cmp.Equals( A[ I ], Value ) then
      Exit( I );
  Result := -1;
end;

// Retire la première occurrence
class function TArrayUtils.Remove<T>( var A: TArray<T>; const Value: T ): Boolean;
var
  Idx: Integer;
begin
  Idx := IndexOf<T>( A, Value );
  Result := Idx >= 0;
  if Result then
    Delete( A, Idx, 1 );
end;

// Retire toutes les occurrences, renvoie le nombre retiré
class function TArrayUtils.RemoveAll<T>( var A: TArray<T>; const Value: T ): Integer;
var
  Cmp: IEqualityComparer<T>;
  I, J: Integer;
begin
  Cmp := TEqualityComparer<T>.Default;
  J := 0;
  for I := 0 to High( A ) do
    if not Cmp.Equals( A[ I ], Value ) then
    begin
      if I <> J then
        A[ J ] := A[ I ];
      Inc( J );
    end;
  Result := Length( A ) - J;
  SetLength( A, J );
end;

end.