I didn't even know this was supported in normal awk.

In mawk the printing does not work like expected (as a for loop over the array does not go necessarily in the order that it was split:

$ SIXEL_CAPABLE=false mawk '
BEGIN{
    OFS=" ";
    a="fortune inthebeginning warhammer_quote bashorg_quote chuck mandelbrot asciidragon just_one_taoup";
    split(a,b);

    if(ENVIRON["SIXEL_CAPABLE"]=="true") {
        print a
    } else {
        for(i in b)
            if(b[i]!="inthebeginning")
                printf "%s%s", b[i], (i<length(b)?OFS:ORS);
    };
}'
warhammer_quote just_one_taoup
mandelbrot chuck fortune bashorg_quote asciidragon

Explicit looping in order works:

SIXEL_CAPABLE=false mawk '
BEGIN{
    OFS=" ";
    a="fortune inthebeginning warhammer_quote bashorg_quote chuck mandelbrot asciidragon just_one_taoup";
    n = split(a,b);

    if(ENVIRON["SIXEL_CAPABLE"]=="true") {
        print a
    } else {
        for(i=1; i<=n; i++)
            if(b[i]!="inthebeginning")
                printf "%s%s", b[i], (i<length(b)?OFS:ORS);
    };
}'
fortune warhammer_quote bashorg_quote chuck mandelbrot asciidragon just_one_taoup

I always "imported" the enviroment variables as an awk variable with the -v option (even for normal awk).

SIXEL_CAPABLE=false frawk -v SIXEL_CAPABLE="${SIXEL_CAPABLE}" '
BEGIN{
    OFS=" ";
    a="fortune inthebeginning warhammer_quote bashorg_quote chuck mandelbrot asciidragon just_one_taoup";
    n = split(a,b);

    if(SIXEL_CAPABLE=="true") {
        print a
    } else {
        for(i=1; i<=n; i++)
            if(b[i]!="inthebeginning")
                printf "%s%s", b[i], (i<length(b)?OFS:ORS);
    };
}'
fortune warhammer_quote bashorg_quote chuck mandelbrot asciidragon just_one_taoup

To implement ENVIRONMENT array support in frawk, you can use this:

SIXEL_CAPABLE=false frawk '
BEGIN {
    # Backup original record separator.
    RS_orig = RS;
    # Lines in "/proc/self/environ" are separated by "\0".
    RS="\0";

    # Read environment variables.
    while( (getline env_line < "/proc/self/environ") > 0 ) {
        # Find "=" position for each environment variable line.
        equalsign_pos = index(env_line, "=");
        # Get environment variable name and value.
        env_name = substr(env_line, 1, equalsign_pos - 1);
        env_value = substr(env_line, equalsign_pos + 1);

        # Store in ENVIRON variable
        ENVIRON[env_name] = env_value;
    }

    # Restore original record separator.
    RS = RS_orig;
}
BEGIN{
    OFS=" ";
    a="fortune inthebeginning warhammer_quote bashorg_quote chuck mandelbrot asciidragon just_one_taoup";
    n = split(a,b);

    if(ENVIRON["SIXEL_CAPABLE"]=="true") {
        print a
    } else {
        for(i=1; i<=n; i++)
            if(b[i]!="inthebeginning")
                printf "%s%s", b[i], (i<length(b)?OFS:ORS);
    };
}'
fortune warhammer_quote bashorg_quote chuck mandelbrot asciidragon just_one_taoup

It would be more convenient if frawk would support gawk -e option:

       -e program-text
       --source program-text
              Use program-text as AWK program source code.  This option allows the easy intermixing of library functions (used via the -f and  --include  options)  with
              source  code entered on the command line.  It is intended primarily for medium to large AWK programs used in shell scripts.  Each argument supplied via -e
              is treated as if it begins with an implicit @namespace "awk" statement.

In that case the following would work create a awk script for the ENVIRON code and include it as first script in frawk:

$ cat environ.awk
BEGIN {
    # Backup original record separator.
    RS_orig = RS;
    # Lines in "/proc/self/environ" are separated by "\0".
    RS="\0";

    # Read environment variables.
    while( (getline env_line < "/proc/self/environ") > 0 ) {
        # Find "=" position for each environment variable line.
        equalsign_pos = index(env_line, "=");
        # Get environment variable name and value.
        env_name = substr(env_line, 1, equalsign_pos - 1);
        env_value = substr(env_line, equalsign_pos + 1);

        # Store in ENVIRON variable
        ENVIRON[env_name] = env_value;
    }

    # Restore original record separator.
    RS = RS_orig;
}

SIXEL_CAPABLE=false frawk -f environ.awk -e '
BEGIN{
    OFS=" ";
    a="fortune inthebeginning warhammer_quote bashorg_quote chuck mandelbrot asciidragon just_one_taoup";
    n = split(a,b);

    if(ENVIRON["SIXEL_CAPABLE"]=="true") {
        print a
    } else {
        for(i=1; i<=n; i++)
            if(b[i]!="inthebeginning")
                printf "%s%s", b[i], (i<length(b)?OFS:ORS);
    };
}'
fortune warhammer_quote bashorg_quote chuck mandelbrot asciidragon just_one_taoup

As long as the -e option does not exist in frawk bash process substitution (<(some command)) can be used to make a temporary file to read with frawk -f:

SIXEL_CAPABLE=false target/release/frawk -f environ.awk  -f <(echo -nE '
BEGIN{
    OFS=" ";
    a="fortune inthebeginning warhammer_quote bashorg_quote chuck mandelbrot asciidragon just_one_taoup";
    n = split(a,b);

    if(ENVIRON["SIXEL_CAPABLE"]=="true") {
        print a
    } else {
        for(i=1; i<=n; i++)
            if(b[i]!="inthebeginning")
                printf "%s%s", b[i], (i<length(b)?OFS:ORS);
    };
}')
fortune warhammer_quote bashorg_quote chuck mandelbrot asciidragon just_one_taoup

ENVIRON variable support? #107

Description

Metadata

Metadata

Assignees

Labels

Projects

Milestone

Relationships

Development

Issue actions