ssync/flake.nix at main · fosskar/ssync · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
{
  description = "ssync — p2p sync of coding-agent session files";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixpkgs-unstable";
    treefmt-nix.url = "github:numtide/treefmt-nix";
    treefmt-nix.inputs.nixpkgs.follows = "nixpkgs";
    nixbot.url = "github:Mic92/nixbot";
    nixbot.inputs.nixpkgs.follows = "nixpkgs";
    nixbot.inputs.treefmt-nix.follows = "treefmt-nix";
  };

  outputs =
    {
      self,
      nixpkgs,
      treefmt-nix,
      nixbot,
      ...
    }:
    let
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];
      forEachSystem = nixpkgs.lib.genAttrs systems;
      pkgsForEach = nixpkgs.legacyPackages;
      treefmtEval = forEachSystem (
        system: treefmt-nix.lib.evalModule pkgsForEach.${system} ./nix/treefmt.nix
      );
    in
    rec {
      packages = forEachSystem (system: {
        default = pkgsForEach.${system}.callPackage ./nix/package.nix { };
      });

      devShells = forEachSystem (system: {
        default = pkgsForEach.${system}.callPackage ./nix/devshell.nix { };
      });

      nixosModules.default = import ./nix/nixos-module.nix { inherit self; };
      homeManagerModules.default = import ./nix/hm-module.nix { inherit self; };
      # clan resolves external services via the `clan.modules.<name>` output.
      clan.modules.ssync = import ./nix/clan-service.nix { inherit self; };

      formatter = forEachSystem (system: treefmtEval.${system}.config.build.wrapper);

      # nixbot scheduled effects (flake input updates via nixfiles' updater)
      herculesCI = import ./nix/effects.nix {
        pkgs = pkgsForEach.x86_64-linux;
        inherit nixbot;
      };

      checks = forEachSystem (
        system:
        import ./nix/checks.nix {
          inherit self system;
          pkgs = pkgsForEach.${system};
          treefmtEval = treefmtEval.${system};
        }
      );

      hydraJobs = packages;
    };
}