ISSUE: _NetWebView2_DecodeB64()

[mlipok]

some issue with DecodeB64()

Can be checked with:

https://github.com/ioa747/NetWebView2Lib/blob/main/examples/5-SaveDemo.au3

[mlipok]

;~ #AutoIt3Wrapper_UseX64=y

; NetWebView2Lib.JsonParser - Tutorial Script

#include <Array.au3>
#include <MsgBoxConstants.au3>

; Global objects handler for COM objects
Global $oMyError = ObjEvent("AutoIt.Error", "_ErrFunc")

_Example()

Func _Example()

	; Initialize the COM Object
	Local $oJson = ObjCreate("NetJson.Parser")
	If Not IsObj($oJson) Then
		MsgBox(16, "Error", "Could not create NetWebView2Lib.JsonParser. Make sure the DLL is registered.")
		Exit
	EndIf

	Local $sRaw = '{"user": "John", "roles": ["Admin", "Tester"], "active": true}'
	$oJson.Parse($sRaw)
	Local $sJSON_String = $oJson.GetJson()

	ConsoleWrite("Full JSON as string: " & $sJSON_String & @CRLF & @CRLF)
	ConsoleWrite("$oJson.EncodeB64: " & $oJson.EncodeB64($sJSON_String) & @CRLF & @CRLF)
	ConsoleWrite("$oJson.DecodeB64: " & $oJson.DecodeB64($oJson.EncodeB64($sJSON_String)) & @CRLF & @CRLF)
	ConsoleWrite("_Base64Encode: " & _Base64Encode($sJSON_String) & @CRLF & @CRLF)
	ConsoleWrite("_Base64Decode: " &  BinaryToString(_Base64Decode(_Base64Encode($sJSON_String))) & @CRLF & @CRLF)
	ConsoleWrite("$oJson.EncodeB64 > _Base64Decode: " & BinaryToString(_Base64Decode($oJson.EncodeB64($sJSON_String))) & @CRLF & @CRLF)

	; Clean up object
	$oJson = Null

EndFunc   ;==>_Example

Func _ErrFunc($oError) ; User's COM error function. Will be called if COM error occurs
	; Do anything here.
	ConsoleWrite(@ScriptName & " (" & $oError.scriptline & ") : ==> COM Error intercepted !" & @CRLF & _
			@TAB & "err.number is: " & @TAB & @TAB & "0x" & Hex($oError.number) & @CRLF & _
			@TAB & "err.windescription:" & @TAB & $oError.windescription & @CRLF & _
			@TAB & "err.description is: " & @TAB & $oError.description & @CRLF & _
			@TAB & "err.source is: " & @TAB & @TAB & $oError.source & @CRLF & _
			@TAB & "err.helpfile is: " & @TAB & $oError.helpfile & @CRLF & _
			@TAB & "err.helpcontext is: " & @TAB & $oError.helpcontext & @CRLF & _
			@TAB & "err.lastdllerror is: " & @TAB & $oError.lastdllerror & @CRLF & _
			@TAB & "err.scriptline is: " & @TAB & $oError.scriptline & @CRLF & _
			@TAB & "err.retcode is: " & @TAB & "0x" & Hex($oError.retcode) & @CRLF & @CRLF)
EndFunc   ;==>_ErrFunc

Func _Base64Encode($input)

    $input = Binary($input)

    Local $struct = DllStructCreate("byte[" & BinaryLen($input) & "]")

    DllStructSetData($struct, 1, $input)

    Local $strc = DllStructCreate("int")

    Local $a_Call = DllCall("Crypt32.dll", "int", "CryptBinaryToString", _
            "ptr", DllStructGetPtr($struct), _
            "int", DllStructGetSize($struct), _
            "int", 1, _
            "ptr", 0, _
            "ptr", DllStructGetPtr($strc))

    If @error Or Not $a_Call[0] Then
        Return SetError(1, 0, "") ; error calculating the length of the buffer needed
    EndIf

    Local $a = DllStructCreate("char[" & DllStructGetData($strc, 1) & "]")

    $a_Call = DllCall("Crypt32.dll", "int", "CryptBinaryToString", _
            "ptr", DllStructGetPtr($struct), _
            "int", DllStructGetSize($struct), _
            "int", 1, _
            "ptr", DllStructGetPtr($a), _
            "ptr", DllStructGetPtr($strc))

    If @error Or Not $a_Call[0] Then
        Return SetError(2, 0, ""); error encoding
    EndIf

    Return DllStructGetData($a, 1)

EndFunc   ;==>_Base64Encode

; #FUNCTION# ====================================================================================================================
; Name ..........: _Base64Decode
; Description ...:
; Syntax ........: _Base64Decode($input_string)
; Parameters ....: $input_string        - An integer value.
; Return values .: None
; Author ........: trancexx
; Modified ......:
; Remarks .......:
; Related .......:
; Link ..........: http://www.autoitscript.com/forum/topic/81332-base64encode-base64decode
; Example .......: yes
; ===============================================================================================================================
Func _Base64Decode($input_string)

	Local $struct = DllStructCreate("int")

	Local $a_Call = DllCall("Crypt32.dll", "int", "CryptStringToBinary", _
			"str", $input_string, _
			"int", 0, _
			"int", 1, _
			"ptr", 0, _
			"ptr", DllStructGetPtr($struct, 1), _
			"ptr", 0, _
			"ptr", 0)

	If @error Or Not $a_Call[0] Then
		Return SetError(1, 0, "") ; error calculating the length of the buffer needed
	EndIf

	Local $a = DllStructCreate("byte[" & DllStructGetData($struct, 1) & "]")

	$a_Call = DllCall("Crypt32.dll", "int", "CryptStringToBinary", _
			"str", $input_string, _
			"int", 0, _
			"int", 1, _
			"ptr", DllStructGetPtr($a), _
			"ptr", DllStructGetPtr($struct, 1), _
			"ptr", 0, _
			"ptr", 0)

	If @error Or Not $a_Call[0] Then
		Return SetError(2, 0, "") ; error decoding
	EndIf

	Return DllStructGetData($a, 1)

EndFunc   ;==>_Base64Decode

take a look:

$oJson.EncodeB64: ew0KICAidXNlciI6ICJKb2huIiwNCiAgInJvbGVzIjogWw0KICAgICJBZG1pbiIsDQogICAgIlRlc3RlciINCiAgXSwNCiAgImFjdGl2ZSI6IHRydWUNCn0=

_Base64Encode: ew0KICAidXNlciI6ICJKb2huIiwNCiAgInJvbGVzIjogWw0KICAgICJBZG1pbiIs
DQogICAgIlRlc3RlciINCiAgXSwNCiAgImFjdGl2ZSI6IHRydWUNCn0=

[mlipok]

$oJson.DecodeB64 returns STRING but there is also a need to get Binary.

NetWebView2Lib/src/WebViewManager.cs

Lines 1585 to 1588 in 1d90326

	try {
	var bytes = Convert.FromBase64String(value);
	return System.Text.Encoding.UTF8.GetString(bytes);
	} catch { return ""; } // Fail safe

for example something like

            try {
                var bytes = Convert.FromBase64String(value);
                return bytes;
            } catch { return ""; } // Fail safe

instead

            try {
                var bytes = Convert.FromBase64String(value);
                return System.Text.Encoding.UTF8.GetString(bytes);
            } catch { return ""; } // Fail safe

Please add parameter to DecodeB64 to be able to do this:

Func _NetJson_DecodeB64($sData, $bReturnBinary = True)
	Local Const $s_Prefix = "[_NetJson_DecodeB64]:"
	Local $oMyError = ObjEvent("AutoIt.Error", __NetWebView2_COMErrFunc) ; Local COM Error Handler
	#forceref $oMyError

	Local $oJSON = _NetJson_CreateParser()
	If @error Then
		__NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)
		Return SetError(@error, @extended, $oJSON)
	EndIf

	Local $dBinary = $oJSON.Decode64($sData, $bReturnBinary)
	If @error Then __NetWebView2_Log(@ScriptLineNumber, $s_Prefix, 1)
	Return SetError(@error, @extended, $dBinary)
EndFunc   ;==>_NetJson_DecodeB64

[ioa747]

I have already scheduled a dedicated method for v1.5.0 called DecodeB64ToBinary.

This way, we keep the original DecodeB64 strictly for strings and have a high-performance binary-only method for PDFs and Images. It will return a raw byte[] which AutoIt will handle perfectly as a Binary type.