build.gradle

import java.nio.charset.StandardCharsets
import java.text.SimpleDateFormat

import com.github.spotbugs.snom.Effort

import org.apache.commons.configuration2.FileBasedConfiguration
import org.apache.commons.configuration2.PropertiesConfiguration
import proguard.gradle.ProGuardTask

buildscript {
    repositories {
        mavenCentral()
        maven {
            url = uri("https://plugins.gradle.org/m2/")
        }
    }
    dependencies {
        classpath 'com.gradleup.shadow:shadow-gradle-plugin:9.4.1'
        classpath 'org.apache.commons:commons-configuration2:2.13.0'
        classpath 'com.guardsquare:proguard-gradle:7.9.0'
        classpath 'com.github.spotbugs.snom:spotbugs-gradle-plugin:6.4.8'
        classpath 'org.sonarsource.scanner.gradle:sonarqube-gradle-plugin:7.2.3.7755'
    }
}

subprojects {
    apply plugin: 'java-library'
    apply plugin: 'com.gradleup.shadow'
    apply plugin: 'checkstyle'
    apply plugin: 'pmd'
    apply plugin: 'idea'
    apply plugin: 'com.github.spotbugs'
    apply plugin: 'jacoco'
    apply plugin: 'org.sonarqube'

    tasks.withType(JavaCompile) {
        options.release = 21
    }

    ext {
        privkeyid = '99'
        privkeyfile = "$rootDir/config/priv_key"
        pubkeyfile = "$rootDir/config/pub_key"
        mxtfile = project.layout.buildDirectory.dir("${rootProject.name}-${project.name}-v${getConfigValueForKey("module_build")}.mxt")
        outjar = project.layout.buildDirectory.dir("proguard-${rootProject.name}-v${getConfigValueForKey("module_build")}.jar")
    }

    repositories {
        mavenCentral()
        flatDir dirs: "$rootDir/lib"
    }

    jar {
        archiveBaseName.set(rootProject.name)
        manifest {
            attributes ((java.util.jar.Attributes.Name.IMPLEMENTATION_TITLE.toString()): getConfigValueForKey("module_name"),
                    (java.util.jar.Attributes.Name.IMPLEMENTATION_VERSION.toString()): getConfigValueForKey("module_build"),
                    (java.util.jar.Attributes.Name.IMPLEMENTATION_VENDOR.toString()): getConfigValueForKey("vendor"),
                    'Built-By': System.getProperty('user.name'),
                    'Built-Date': getCurrentTimestamp(),
                    'Created-By': System.getProperty('java.version') + ' (' + System.getProperty('java.vendor') + ')')

        }
    }

    tasks.named('shadowJar').configure {
        archiveBaseName.set(rootProject.name)
        from 'NOTICE'
        from 'LICENSE'
        exclude 'META-INF/**/*'

        dependencies {
            include project(':core')
            include dependency('org.apache.commons:commons-configuration2:2.13.0')
            include dependency('org.apache.commons:commons-lang3:3.20.0')
            include dependency('org.apache.commons:commons-text:1.15.0')
            include dependency('commons-io:commons-io:2.21.0')
            include dependency('org.slf4j:slf4j-api:2.0.17')
            include dependency('org.slf4j:slf4j-nop:2.0.17')
        }
        relocate 'org.apache.commons.io', 'com.moneydance.modules.features.importlist.org.apache.commons.io'
        relocate 'org.apache.commons.lang3', 'com.moneydance.modules.features.importlist.org.apache.commons.lang3'
        relocate 'org.apache.commons.text', 'com.moneydance.modules.features.importlist.org.apache.commons.text'
        relocate 'org.apache.commons.configuration2', 'com.moneydance.modules.features.importlist.org.apache.commons.configuration2'
    }

    tasks.register('proguard', ProGuardTask) {
        dependsOn 'shadowJar'
        injars  shadowJar.archiveFile.get().asFile
        outjars outjar.get().asFile
        configuration 'config/proguard.cfg'
    }

    tasks.named('proguard').configure {
        doLast {
            outjar.get().asFile.renameTo(file(mxtfile))
        }
    }

    checkstyle {
        toolVersion = '10.25.0'
    }

    pmd {
        consoleOutput = true
        toolVersion = "7.19.0"
        ruleSets = []
        ruleSetFiles = files("$rootDir/config/pmd-ruleSet.xml")
    }

    tasks.withType(Pmd) {
        enabled = it.name.endsWith('Main')
    }

    spotbugs {
        toolVersion = "4.9.3"
        effort = Effort.valueOf('MAX')
        excludeFilter = file("$rootDir/config/spotbugs-exclude.xml")
    }

    jacoco {
        toolVersion = "0.8.13"
    }

    sonar {
        properties {
            property "sonar.host.url", "https://sonarcloud.io"
            property "sonar.organization", "my-flow"
        }
    }
}

String getCurrentTimestamp() {
    Date today = new Date()
    SimpleDateFormat df = new SimpleDateFormat('yyyy-MM-dd HH:mm:ss')
    return df.format(today)
}

String getConfigValueForKey(String key) {
    file("${project(':core').projectDir}/src/main/resources/com/moneydance/modules/features/importlist/meta_info.dict").withInputStream {
        final FileBasedConfiguration config = new PropertiesConfiguration();
        config.read(new InputStreamReader(it, StandardCharsets.UTF_8))
        return config.getString("\"" + key + "\"").replaceAll("^\"|\"\$", "");
    }
}