Connectivity Manager and Network Commissioning Drivers Need to be More Flexible for Linux

[gerickson]

Matter currently supports as first-class network technologies: Bluetooth, Thread, Wi-Fi, and Ethernet with Bluetooth reserved only for commissioning, and Thread, Wi-Fi, and Ethernet as either on-network commissioning networks and/or operational networks.

On Linux, BlueZ and the bluetoothd daemon is the de facto Bluetooth implementation.

For Thread, OpenThread is the de facto Thread implementation.

However, for Ethernet and Wi-Fi, things are more diverse.

In the nominal case (and currently in Matter), the Ethernet control plane has no management software whatsoever beyond the Linux kernel and the Wi-Fi control plane is handled by the wpa_supplicant daemon over D-Bus.

However, there are several further variants:

1. Instead of wpa_supplicant, Wi-Fi may be managed by iwd.
2. Rather than being managed heterogeneously, as they are today in Matter, Ethernet, Wi-Fi, and, in some instances Cellular, may be further managed by one of:
   1. connman with:
      1. Ethernet sub-managed by connman itself.
      2. Wi-Fi sub-managed by either:
         1. iwd
         2. wpa_supplicant
      3. Cellular managed by oFono.
   2. NetworkManager
      1. Ethernet sub-managed by NetworkManager itself.
      2. Wi-Fi sub-managed by either:
         1. iwd
         2. wpa_supplicant
      3. Cellular managed by ModemManager.
   3. All of networking is managed by some proprietary product- or platform-specific entity for which any of the above may be a backing implementation.
      1. Regardless, like ConfigurationManager today, there may be a desire to default the Matter build to (1) or (2) but then set a custom ConnectivityManager at runtime with a potential chip::DeviceLayer::SetConnectivityMgr.

There are several implementation implications of this:

1. On the Linux platform, there should be a better ability to mix-and-match and/or override implementation details. For example, maintaining the default BlueZ Bluetooth implementation while substituting connman or NetworkManager for both Ethernet and Wi-Fi management or wpa_supplicant or iwd for Wi-Fi management.
   1. In the case of connman or NetworkManager, they own the configuration / provisioning state for the Wi-Fi network(s).
2. Particularly for connman, scans do not necessarily return signal strength as RSSI / dBm. Rather, they return values on a qualitative scale from 0-100.
   1. Consequently, scan results should be able to indicate whether the results are quantitative, qualitative, both, or neither.
3. There should likely be a chip::DeviceLayer::SetConnectivityMgr peer to chip::DeviceLayer::SetConfigurationMgr.

Matter ConnectivityManager Linux Platform Refactoring tries to illustrate this a bit better.

/cc @holtmann, @denkenz

[gerickson]

There appears to be an issue if both Matter and connmand attempt to have a D-Bus control interface to wpa_supplicant.

This should work.

[gerickson]

Directionally, something akin to this for src/platform/Linux/BUILD.gn is where I am headed with this:

diff --git a/src/platform/Linux/BUILD.gn b/src/platform/Linux/BUILD.gn
index e83f7f714d2b..1fff413741c1 100644
--- a/src/platform/Linux/BUILD.gn
+++ b/src/platform/Linux/BUILD.gn
@@ -24,6 +24,27 @@ import("${chip_root}/src/crypto/crypto.gni")
 
 assert(chip_device_platform == "linux")
 
+declare_args() {
+    # The Linux high-level network manager, if any, that owns network
+    # policy and state and orchestrates connectivity decisions and
+    # cross-interface policy.
+    #
+    # This may be one of "none", "connman", or "networkmanager".
+    chip_linux_network_manager = "none"
+
+    # The Linux low-level Wi-Fi control plane manager that drives the
+    # Wi-Fi MAC and PHY through the Linux nl80211 driver.
+    #
+    # This is used when the 'chip_linux_network_manager' is "none"
+    # (direct Wi-Fi management) or when
+    # 'chip_device_config_enable_wifipaf' is true (use Wi-Fi Neighbor
+    # Awareness Networking (NAN) Unsynchronized Service Discovery
+    # (USD) / Public Action Frame (PAF) commissioning transport).
+    #
+    # This may be one of "iwd" or "wpa_supplicant".
+    chip_linux_wifi_control_manager = "wpa_supplicant"
+}
+
 if (chip_enable_openthread) {
   import("//build_overrides/openthread.gni")
 }
@@ -166,9 +187,87 @@ static_library("Linux") {
   }
 
   if (chip_enable_wifi) {
+    assert(chip_linux_network_manager == "none"    ||
+           chip_linux_network_manager == "connman" ||
+           chip_linux_network_manager == "networkmanager",
+           "chip_linux_network_manager must be one of: none, connman, networkmanager")
+
+    assert(chip_linux_wifi_control_manager == "iwd" ||
+           chip_linux_wifi_control_manager == "wpa_supplicant",
+           "chip_linux_wifi_control_manager must be one of: iwd, wpa_supplicant")
+
     sources += [ "NetworkCommissioningWiFiDriver.cpp" ]
 
-    public_deps += [ "dbus/wpa" ]
+    defines = [
+      "CHIP_LINUX_NETWORK_MANAGER=\"${chip_linux_network_manager}\"",
+      "CHIP_LINUX_WIFI_CONTROL_MANAGER=\"${chip_linux_wifi_control_manager}\"",
+    ]
+
+    if (chip_linux_network_manager == "none") {
+      defines += [ "CHIP_LINUX_NETWORK_MANAGER_NONE=1" ]
+
+      if (chip_linux_wifi_control_manager == "wpa_supplicant") {
+        sources += [
+          "ConnectivityManagerImpl_WiFiWpaSupplicant.cpp",
+          "ConnectivityManagerImpl_WiFiWpaSupplicant.h"
+        ]
+      } else if (chip_linux_wifi_control_manager == "iwd") {
+        sources += [
+          "ConnectivityManagerImpl_WiFiIwd.cpp",
+          "ConnectivityManagerImpl_WiFiIwd.h"
+        ]
+      }
+    } else if (chip_linux_network_manager == "connman") {
+      defines += [ "CHIP_LINUX_NETWORK_MANAGER_CONNMAN=1" ]
+
+      sources += [
+        "ConnectivityManagerImpl_WiFiConnMan.cpp",
+        "ConnectivityManagerImpl_WiFiConnMan.h"
+      ]
+
+      public_deps += [ "dbus/connman" ]
+    } else if (chip_linux_network_manager == "networkmanager") {
+      defines += [ "CHIP_LINUX_NETWORK_MANAGER_NETWORKMANAGER=1" ]
+
+      sources += [
+        "ConnectivityManagerImpl_WiFiNetworkManager.cpp",
+        "ConnectivityManagerImpl_WiFiNetworkManager.h"
+      ]
+
+      public_deps += [ "dbus/networkmanager" ]
+    } else {
+      assert(false, "Linux network manager not specified or not supported: " + chip_linux_network_manager)
+    }
+
+    need_wifi_control_manager = (chip_linux_network_manager == "none") || chip_device_config_enable_wifipaf
+
+    if (need_wifi_control_manager) {
+      if (chip_linux_wifi_control_manager == "iwd") {
+        defines += [ "CHIP_LINUX_WIFI_CONTROL_MANAGER_IWD=1" ]
+
+        if (chip_device_config_enable_wifipaf) {
+          sources += [
+            "ConnectivityManagerImpl_WiFiPafIwd.cpp",
+            "ConnectivityManagerImpl_WiFiPafIwd.h"
+          ]
+        }
+
+        public_deps += [ "dbus/iwd" ]
+      } else if (chip_linux_wifi_control_manager == "wpa_supplicant") {
+        defines += [ "CHIP_LINUX_WIFI_CONTROL_MANAGER_WPA_SUPPLICANT=1" ]
+
+        if (chip_device_config_enable_wifipaf) {
+          sources += [
+            "ConnectivityManagerImpl_WiFiPafWpaSupplicant.cpp",
+            "ConnectivityManagerImpl_WiFiPafWpaSupplicant.h"
+          ]
+        }
+
+        public_deps += [ "dbus/wpa" ]
+      } else {
+        assert(false, "Linux Wi-Fi control manager not specified or not supported: " + chip_linux_wifi_control_manager)
+      }
+    }
   }
 
   if (chip_enable_ble) {

More granularity might be necessary as certain things may still require direct wpa_supplicant or iwd access with connman or NetworkManager with or without NAN USD / PAF.

[gerickson]

With the above, if we create a custom development build host configuration, including:

• chip_enable_wifi=true
• chip_linux_network_manager="none"
• chip_linux_wifi_control_manager="wpa_supplicant"

we end up with:

• obj/src/platform/Linux/Linux.ConnectivityManagerImpl.cpp.o
• obj/src/platform/Linux/Linux.ConnectivityManagerImpl_WiFiPafWpaSupplicant.cpp.o
• obj/src/platform/Linux/Linux.ConnectivityManagerImpl_WiFiWpaSupplicant.cpp.o

as expected. Likewise, if we create a custom target configuration, including:

• chip_enable_wifi=true
• chip_linux_network_manager="connman"
• chip_linux_wifi_control_manager="wpa_supplicant"

we end up with:

• obj/src/platform/Linux/Linux.ConnectivityManagerImpl.cpp.o
• obj/src/platform/Linux/Linux.ConnectivityManagerImpl_WiFiConnMan.cpp.o
• obj/src/platform/Linux/Linux.ConnectivityManagerImpl_WiFiPafWpaSupplicant.cpp.o

as expected.

[gerickson]

The Linux kernel header include/net/cfg80211.h has some inspiration for handling signal strength:

/**
 * enum cfg80211_signal_type - signal type
 *
 * @CFG80211_SIGNAL_TYPE_NONE: no signal strength information available
 * @CFG80211_SIGNAL_TYPE_MBM: signal strength in mBm (100*dBm)
 * @CFG80211_SIGNAL_TYPE_UNSPEC: signal strength, increasing from 0 through 100
 */
enum cfg80211_signal_type {
    CFG80211_SIGNAL_TYPE_NONE,
    CFG80211_SIGNAL_TYPE_MBM,
    CFG80211_SIGNAL_TYPE_UNSPEC,
};

[enkiusz]

Partially fixed, closed by mistake it seems.

[gerickson]

Partially fixed, closed by mistake it seems.

Confirmed; thank you.