Hi Sir ! I actually DOWNLOAD THE STICK RPG2 ON ZIP FILE (WINDOW 7 version) And i like to know how to APPLY this effect on ZIP FILE and NOT ON STEAM GAME

[barbarosabarons-oss]

Please need explanation

[XxGrandisxX]

1- make a back up of the whole folder
2- go to the .bat file and change the
start steam://launch/307640
to the path of your file (be sure to include the .exe file name aswell {ex : PATH/ STICK RPG 2.exe},and also search how to start a .exe file in a .bat)
3- download correct version of flash players because the one in archive.org right now isnt working (you can send chatGPT the .bat file and it will search for it based of the hash that its trying to verify)
4 - paste that flash player file into your game folder
5 - run the install_stickrpg2_hd.bat file
6 - to play the run the Stick RPG 2 Director's Cut.exe not the orignial.exe

[KevinGuest]

@echo off
cls

set "PATCH=%CD%\patch"
timeout /t 3 >nul

set "exepath=C:\Users\[REPLACE_WITH_USER]\[PATH]\StickRPG\Stick RPG 2 Director's Cut.exe"
echo Found Stick RPG 2 in %exepath%
for %%a in ("%exepath%") do (
    cd /d "%%~dpa"
)

taskkill /F /IM "Stick RPG 2 Director's Cut.exe"

IF NOT EXIST original.exe (
    echo Creating a backup of the original game as original.exe
    copy "Stick RPG 2 Director's Cut.exe" "original.exe"
)
rem Reset the main file and SWFs just in case we need to reinstall
del *.swf
del "Stick RPG 2 Director's Cut.exe"
copy "original.exe" "Stick RPG 2 Director's Cut.exe"

echo Downloading required files...

echo Downloading flashplayer_32_sa.exe...
IF NOT EXIST flashplayer_32_sa.exe (
    %WINDIR%\System32\curl.exe -L -o flashplayer_32_sa.exe https://archive.org/download/adobe-flash-player-32.0.0.465-retail-debug/flashplayer_32_sa.exe
)
echo Download complete, verifying...
certutil -hashfile flashplayer_32_sa.exe SHA256 | %WINDIR%\System32\find.exe "a4b333ac1da12026989549015303d82231982838bccfb544ba5fd188746066f0"
if errorlevel 1 (
    echo Error verifying the hash of flashplayer_32_sa.exe, the file may be corrupted or modified.
    pause
    EXIT
)
echo Download verified successfully!

echo Downloading xdelta3-3.1.0-x86_64.exe.zip...
IF NOT EXIST xdelta3-3.1.0-x86_64.exe.zip (
    %WINDIR%\System32\curl.exe -L -o xdelta3-3.1.0-x86_64.exe.zip https://github.com/jmacd/xdelta-gpl/releases/download/v3.1.0/xdelta3-3.1.0-x86_64.exe.zip
)
echo Download complete, verifying...
certutil -hashfile xdelta3-3.1.0-x86_64.exe.zip SHA256 | %WINDIR%\System32\find.exe "b10e0d1df3e212e5a2d37d5c088d2f72ecec760bc3c26caeca51499c3118b93a"
if errorlevel 1 (
    echo Error verifying the hash of xdelta3-3.1.0-x86_64.exe.zip, the file may be corrupted or modified.
    pause
    EXIT
)
echo Download verified successfully!

echo Forcing TMP env and collecting files...
set "OLD_TMP=%TMP%"
set "TMP=%CD%"
echo Launching Stick RPG 2...
start "stick" "Stick RPG 2 Director's Cut.exe"
echo Waiting 10 seconds for the game to start...
timeout /t 10 /nobreak>nul
set "TMP=%OLD_TMP%"
echo Killing the game process...
taskkill /F /IM "Stick RPG 2 Director's Cut.exe"
echo Rearranging files...
mkdir data
mkdir data\combat
move racer-attributes.txt data\
move srpg2_*.xml data\
move *.xml data\combat\
mkdir maps
mkdir maps\559
move __*.dat maps\559\
echo Preparing to patch files...
IF NOT EXIST xdelta3-3.1.0-x86_64.exe (
    %WINDIR%\System32\tar.exe -xf xdelta3-3.1.0-x86_64.exe.zip
)
echo Patching flashplayer_32_sa...
xdelta3-3.1.0-x86_64.exe -d -s flashplayer_32_sa.exe "%PATCH%\projector.patch" flashplayer_patched.exe
echo Patching HD textures for dat.swf...
ren dat.swf dat_original.swf
xdelta3-3.1.0-x86_64.exe -d -s dat_original.swf "%PATCH%\dat.swf.texturepatch" dat.swf
echo Patching HD textures for Minigames.swf...
ren Minigames.swf Minigames_original.swf
xdelta3-3.1.0-x86_64.exe -d -s Minigames_original.swf "%PATCH%\Minigames.swf.texturepatch" Minigames.swf

echo Creating final HD exe...
del "Stick RPG 2 Director's Cut.exe"
copy /b flashplayer_patched.exe + "Zinc Shell Mac.swf" + "%PATCH%\finalize.hex" "Stick RPG 2 Director's Cut.exe"

echo Linking saves...
for /d %%D in ("%APPDATA%\Macromedia\Flash Player\#SharedObjects\*") do (
    mkdir "%%~fD\localhost\%cd:~3%"
    mkdir "%%~fD\localhost\%cd:~3%\Minigames.swf"
    mklink /h "%%~fD\localhost\%cd:~3%\Minigames.swf\srpg2Save.sol" "%%~fD\localhost\%cd:~3%\..\Minigames.swf\srpg2Save.sol"
)

echo Done! Press any key to exit.
pause>nul