runecode/flake.nix at main · runecode-systems/runecode · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
{
  description = "RuneCode dev environment and canonical release builder (Nix >= 2.18)";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-25.11";
    flake-utils.url = "github:numtide/flake-utils";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
    }:
    let
      releaseMetadata = import ./nix/release/metadata.nix;
    in
    flake-utils.lib.eachDefaultSystem (
      system:
      let
        pkgs = import nixpkgs { inherit system; };
        lib = pkgs.lib;
        goToolchain = pkgs.go_1_25 or (throw "nixpkgs must provide go_1_25 for RuneCode release builds");

        releaseArtifacts = import ./nix/packages/release-artifacts.nix {
          inherit
            goToolchain
            lib
            pkgs
            self
            ;
          releaseMetadata = releaseMetadata;
        };

        tla2toolsJar = import ./nix/packages/tla2tools-jar.nix {
          inherit pkgs;
        };

        devShell = import ./nix/dev-shell.nix {
          inherit goToolchain pkgs;
        };

        checks = import ./nix/checks.nix {
          inherit
            devShell
            lib
            pkgs
            releaseMetadata
            releaseArtifacts
            self
            system
            ;
        };
      in
      {
        formatter = pkgs.nixfmt-rfc-style;

        devShells.default = devShell;

        packages = {
          release-artifacts = releaseArtifacts;
          tla2tools-jar = tla2toolsJar;
        };

        inherit checks;
      }
    )
    // {
      lib.release = releaseMetadata;
    };
}