hydra-structlog/justfile at main · szapp/hydra-structlog · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
alias setup := install
alias sync := install
alias update := install

# List all commands by default when typing only `just``
@_default:
    just --list

#########
# CHECK #
#########

# Lint and format
[group('check')]
lint:
    uv run ruff check --fix
    uv run ruff format

# Check types
[group('check')]
typing:
    uv run ty check src

# Check coverage (pytest)
[group('check')]
cov *args:
    uv run pytest {{ args }}

# Run all tests on all dependency combinations (nox)
[group('check')]
test *args:
    uv run nox {{ args }}

# Check docstrings on tests
[group('check')]
check-testdocs:
    uv run interrogate tests

# Run linting, formatting, tests and type-checking
[group('check')]
check-all: lint cov test typing check-testdocs

##############
# LIFE CYCLE #
##############

# Bring environment up-to-date
[group('lifecycle')]
install:
    uv sync
    uv run prek install --install-hooks --overwrite --no-progress

# Reset environment and all cache files
[group('lifecycle')]
clean:
    uvx pyclean . -d all
    uvx prek uninstall --no-progress
    -rm -rf .venv

# Setup environment from scratch
[group('lifecycle')]
fresh: clean install

# Upgrade python and all dependencies
[group('lifecycle')]
upgrade:
    uv sync --upgrade
    uv run prek auto-update --no-progress